home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / BEAGLE.BAG.SHK / BEAGLE.BAG / MAGIC PACK.bas < prev    next >
BASIC Source File  |  2000-01-01  |  20KB  |  448 lines
  1. 90  REM <CTRL-M><CTRL-M>==================<CTRL-M>MAGIC PACK<CTRL-M>BY BERT KERSEY<CTRL-M>COPYRIGHT (C) 1980<CTRL-M>BEAGLE BROS<CTRL-M>==================
  2. 100  FOR I = 1 TO 40:A$ = A$ +".": NEXT : TEXT : HOME : FOR I = 1 TO 22: PRINT A$;: NEXT : VTAB 8
  3. 101  INVERSE : CALL  -868: PRINT " MAGIC PACK ": NORMAL : FOR I = 1 TO 40: PRINT "-";: NEXT : PRINT "HELLO. PLEASE FOLLOW THE INSTRUCTIONS INTHE MANUAL, OR THE FOLLOWING TRICKS WILLNOT WORK PROPERLY (EVEN THOUGH THEY WILLAPPEAR TO BE WORKING).";
  4. 102  CALL  -868: PRINT : PRINT "------": VTAB 24: PRINT "HIT ANY KEY TO START MAGIC PACK:";: GET A$: PRINT A$;
  5. 140  GOSUB 32000: ONERR  GOTO 63900
  6. 142  GOTO 240
  7. 170  REM <CTRL-M><CTRL-M>MENU:<CTRL-M>-----
  8. 180  IF II = 2  THEN 182
  9. 181  FOR I = 22 TO J  STEP  -1: VTAB I: PRINT A$: CALL  -868
  10. 182  IF II < >2  THEN 220
  11. 184  VTAB J: PRINT A$: RETURN 
  12. 220 S =  PEEK( -16336)
  13. 230  NEXT I: RETURN 
  14. 240 A$ = "                                        ":J = 1: GOSUB 180
  15. 250 A$ = "           MAGIC PACK                  ":J = 4: GOSUB 180
  16. 260 A$ = "        -----------------------":J = 5: GOSUB 180
  17. 270 A$ = "        1. PLENTY QUESTIONS":J = 7: GOSUB 180:A$ = "        2. 21 NUMBERS":J = 9: GOSUB 180
  18. 280 A$ = "        3. NEXTWORD":J = 11: GOSUB 180:A$ = "        4. CARD SCANNER":J = 13: GOSUB 180
  19. 290 A$ = "        -----------------------":J = 15: GOSUB 180:A$ = "           BY BEAGLE BROS":J = 16: GOSUB 180
  20. 300  IF II = 2  THEN 310
  21. 305  FOR I = 1 TO 400: NEXT I
  22. 310  FOR I = 1 TO 7
  23. 320  POKE 0,55 -I *7
  24. 330  POKE 1,5
  25. 340  CALL MU
  26. 350  NEXT I: VTAB 22: HTAB 9: PRINT "(TYPE Q TO QUIT.)"
  27. 360  FOR J = 7 TO 13  STEP 2: VTAB J: HTAB 5: PRINT "?": NEXT J
  28. 370 A$ = "  -        ":C$ = "  >        "
  29. 375 A = 0
  30. 380 A = A +1: IF A = 5  THEN 405
  31. 382  FOR I = 4 TO 10  STEP 2: FOR J = 1 TO 11
  32. 385 K =  PEEK(Q) -176: IF (K >0  AND K <5)  OR K = 33  THEN 410
  33. 390  VTAB I +J
  34. 391  HTAB 6
  35. 392  PRINT  MID$ (A$,J,1); MID$ (C$,J,1)
  36. 393  NEXT J
  37. 400  FOR J = 1 TO 50: NEXT J,I: GOTO 380
  38. 405  VTAB 18: HTAB 12: INVERSE : PRINT " HURRY UP! ": NORMAL : FOR I = 1 TO 50:S =  PEEK(Q +48): NEXT I: GOTO 380
  39. 410  POKE Q +16,0: IF K = 33  THEN 63900
  40. 420  ON K GOTO 450,1920,6000,2930
  41. 430  REM <CTRL-M><CTRL-M>================<CTRL-M>PLENTY QUESTIONS<CTRL-M>================
  42. 450 S$ = "":TURN = 3:CHEET = 0: VTAB 4: HTAB 1: CALL  -958: REM NEW GAME
  43. 451  IF B <50  THEN 460
  44. 452 B = 0
  45. 455 TT = 0: FOR I = 1 TO 100:A(I) = 0:B(I) = 0: NEXT I
  46. 460  HOME : PRINT ":::::::::::::::::::::::::::::::::::::::": PRINT ":";: INVERSE : PRINT "    LET'S PLAY 'PLENTY-QUESTIONS!'   ";: NORMAL 
  47. 465  COLOR= 2: VLIN 2,3 AT 16: VLIN 2,3 AT 34
  48. 470  PRINT ":": PRINT ":::::::::::::::::::::::::::::::::::::::"
  49. 480 T$ = " YOU THINK OF AN OBJECT,": HTAB 20 - INT( LEN(T$)/2): GOSUB 5000: FLASH : HTAB 25: PRINT "OBJECT": NORMAL 
  50. 485 T$ = "AND I'LL ASK THE QUESTIONS.": HTAB 20 - INT( LEN(T$)/2)
  51. 487  GOSUB 5000
  52. 488  PRINT 
  53. 522  POKE Q +16,0: VTAB 6: HTAB 1: PRINT "     -----------------------------": VTAB 4: HTAB 25: PRINT "OBJECT"
  54. 525  VTAB 7: HTAB 7: FLASH : PRINT " ";: NORMAL : PRINT "(HIT ANY KEY WHEN READY.)"
  55. 526 K =  PEEK(Q): IF K <129  THEN 526
  56. 527  POKE Q +16,0: IF K = 129  THEN CHEET = 1: REM K=ASC(CTRL-A)
  57. 529  VTAB 7: CALL  -958:J = 0
  58. 530 J = J +1:TURN = TURN +1: IF TURN >21  THEN TURN = 21
  59. 535  INVERSE : VTAB 3 +TURN: HTAB 1: IF J <10  THEN  PRINT " ";
  60. 537  PRINT J;".";
  61. 540  FOR I = 1 TO 9
  62. 550  POKE 0,20 -2 *I +J *9
  63. 560  POKE 1,4
  64. 570  CALL MU
  65. 580  NEXT I
  66. 585  NORMAL : VTAB 3 +TURN: HTAB 1: IF J <10  THEN  PRINT " ";
  67. 586  PRINT J;".";
  68. 588 A(J) =  INT( RND(1) *70) +1: IF B(A(J)) = 1  THEN 588
  69. 593 B(A(J)) = 1:B = B +1: IF A(J) >50  THEN 596
  70. 594  ON A(J) GOSUB 601,602,603,604,605,606,607,608,609,610,611,612,613,614,615,616,617,618,619,620,621,622,623,624,625,626,627,628,629,630,631,632,633,634,635,636,637,638,639,640,641,642,643,644,645,646,647,648,649,650
  71. 595  GOTO 597
  72. 596 A(J) = A(J) -50: ON A(J) GOSUB 651,652,653,654,655,656,657,658,659,660,661,662,663,664,665,666,667,668,669,670
  73. 597  GOSUB 5000: GOSUB 1340
  74. 598  IF J <17  THEN 530
  75. 599  GOTO 1440
  76. 600  REM === QUESTIONS ===
  77. 601 T$ = "DOES IT HAVE TEETH?": RETURN 
  78. 602 T$ = "IS IT ROUND?": RETURN 
  79. 603 T$ = "IS IT HEAVIER THAN A CAR?": RETURN 
  80. 604 T$ = "CAN YOU RIDE IT?": RETURN 
  81. 605 T$ = "DOES IT HAVE MOVING PARTS?": RETURN 
  82. 606 T$ = "DOES IT COST MORE THAN $4?": RETURN 
  83. 607 T$ = "IS IT PAINTED?": RETURN 
  84. 608 T$ = "CAN YOU EAT IT?": RETURN 
  85. 609 T$ = "DOES IT HAVE DRAWERS?": RETURN 
  86. 610 T$ = "IS IT BIGGER THAN A CAT?": RETURN 
  87. 611 T$ = "DO YOU WEAR IT?": RETURN 
  88. 612 T$ = "IS IT EVER BLUE?": RETURN 
  89. 613 T$ = "IS THERE ONE IN THIS ROOM?": RETURN 
  90. 614 T$ = "IS IT NOISY?": RETURN 
  91. 615 T$ = "IS IT SHINY?": RETURN 
  92. 616 T$ = "DOES IT COST OVER $500?": RETURN 
  93. 617 T$ = "IS IT PART CHINESE?": RETURN 
  94. 618 T$ = "CAN YOU WRITE ON IT?": RETURN 
  95. 619 T$ = "DOES IT WRINKLE?": RETURN 
  96. 620 T$ = "CAN YOU BEND IT?": RETURN 
  97. 621 T$ = "DOES IT HAVE WHEELS?": RETURN 
  98. 622 T$ = "CAN IT FLOAT?": RETURN 
  99. 623 T$ = "DOES IT FLY?": RETURN 
  100. 624 T$ = "DOES IT COST OVER $1000?": RETURN 
  101. 625 T$ = "DOES IT SMELL BAD?": RETURN 
  102. 626 T$ = "IS IT HAIRY?": RETURN 
  103. 627 T$ = "IS IT SQUISHY?": RETURN 
  104. 628 T$ = "CAN YOU THROW IT?": RETURN 
  105. 629 T$ = "CAN IT SWIM?": RETURN 
  106. 630 T$ = "COULD IT HOLD WATER?": RETURN 
  107. 631 T$ = "IS IT USUALLY COLD?": RETURN 
  108. 632 T$ = "IS IT BREAKABLE?": RETURN 
  109. 633 T$ = "IS IT ELECTRICAL?": RETURN 
  110. 634 T$ = "CAN YOU SEE ONE HERE?": RETURN 
  111. 635 T$ = "IS IT EVER BROWN?": RETURN 
  112. 636 T$ = "WILL IT BURN?": RETURN 
  113. 637 T$ = "IS IT FUZZY?": RETURN 
  114. 638 T$ = "IS IT HEAVIER THAN AIR?": RETURN 
  115. 639 T$ = "DOES IT START WITH 'Q'?": RETURN 
  116. 640 T$ = "DOES IT MAKE YOU ITCH?": RETURN 
  117. 641 T$ = "IS IT BIGGER THAN A PIG?": RETURN 
  118. 642 T$ = "IS IT A SCARY THING?": RETURN 
  119. 643 T$ = "DOES IT HAVE BATTERIES?": RETURN 
  120. 644 T$ = "IS IT STICKY?": RETURN 
  121. 645 T$ = "IS ONE IN YOUR POCKET?": RETURN 
  122. 646 T$ = "IS IT HARD TO SEE?": RETURN 
  123. 647 T$ = "CAN YOU CARRY IT?": RETURN 
  124. 648 T$ = "IS IT PINK?": RETURN 
  125. 649 T$ = "IS IT FLEXIBLE?": RETURN 
  126. 650 T$ = "IS IT TASTY?": RETURN 
  127. 651 T$ = "CAN YOU THUMP IT?": RETURN 
  128. 652 T$ = "CAN YOU DENT IT?": RETURN 
  129. 653 T$ = "IS IT WASHABLE?": RETURN 
  130. 654 T$ = "DOES IT RATTLE?": RETURN 
  131. 655 T$ = "DOES IT START WITH 'T'?": RETURN 
  132. 656 T$ = "WAS IT INVENTED BY 1800?": RETURN 
  133. 657 T$ = "COULD A DUCK SIT ON IT?": RETURN 
  134. 658 T$ = "IS IT MULTI-COLORED?": RETURN 
  135. 659 T$ = "HAVE YOU SEEN ONE TODAY?": RETURN 
  136. 660 T$ = "DOES IT MOO?": RETURN 
  137. 661 T$ = "WILL IT FIT IN A CAN?": RETURN 
  138. 662 T$ = "CAN YOU RE-USE IT?": RETURN 
  139. 663 T$ = "ARE THERE ANY LUMPY ONES?": RETURN 
  140. 664 T$ = "DOES IT HAVE 5 LETTERS?": RETURN 
  141. 665 T$ = "DID POPEYE HAVE ONE?": RETURN 
  142. 666 T$ = "DOES IT HAVE LEGS?": RETURN 
  143. 667 T$ = "IS IT A GOOD INVESTMENT?": RETURN 
  144. 668 T$ = "DOES IT NEED FIXING A LOT?": RETURN 
  145. 669 T$ = "DOES IT GLITTER?": RETURN 
  146. 670 T$ = "IS IT MADE IN JAPAN?": RETURN 
  147. 1330  REM === GET ANSWERS ===
  148. 1340  VTAB 3 +TURN: HTAB 31: PRINT " ________";: VTAB 3 +TURN: HTAB 32: FLASH : PRINT "_";: NORMAL 
  149. 1345  IF CHEET = 0  THEN 1360
  150. 1350 K =  PEEK(Q): IF K <136  THEN 1350
  151. 1352  POKE Q +16,0
  152. 1355  VTAB 2: HTAB 30: INVERSE : PRINT "1": NORMAL 
  153. 1360  VTAB 3 +TURN: HTAB 32: INPUT "";Q$: VTAB 2: HTAB 30: INVERSE : PRINT "I": NORMAL 
  154. 1361  IF Q$ = ""  THEN 1340
  155. 1362  IF  RIGHT$(Q$,1) = "."  THEN 1435
  156. 1365  IF CHEET = 0  OR K = 149  THEN  RETURN 
  157. 1370  IF K >159  THEN S$ = S$ + CHR$(K -128)
  158. 1400  IF K < >136  THEN 1405
  159. 1401  IF  LEN(S$) >1  THEN S$ =  LEFT$(S$, LEN(S$) -1): GOTO 1405: REM <-
  160. 1402 S$ = ""
  161. 1405  IF  RIGHT$(S$,1) = "/"  THEN S$ = ""
  162. 1410  IF  RIGHT$(S$,1) = "."  OR  RIGHT$(S$,1) = ","  OR  RIGHT$(S$,1) = ";"  THEN 1435
  163. 1420  RETURN 
  164. 1430  REM === PRINT ANSWER ===
  165. 1435  POP 
  166. 1440  IF TURN >19  THEN TURN = 19
  167. 1442  HTAB 12: PRINT :T = 0: FOR I = 1 TO 50:X =  PEEK(Q +48): NEXT I
  168. 1445 T$ = "I'VE GOT IT!": VTAB 5 +TURN: HTAB 14: GOSUB 5000
  169. 1460  IF  RIGHT$(S$,1) = ";"  THEN S$ = "LIGHT BULB."
  170. 1470  FOR I = 1 TO 500: NEXT I
  171. 1480  PRINT : HTAB 12:T$ = "IT'S A ": GOSUB 5000
  172. 1500  IF S$ = "."  THEN S$ = "TUNA SANDWICH."
  173. 1505  IF  RIGHT$(S$,1) < >","  AND CHEET >0  THEN 1540
  174. 1506 RN =  INT( RND(1) *50) +1: IF RN >25  THEN 1509
  175. 1507  ON RN GOSUB 1650,1651,1652,1653,1654,1655,1656,1657,1658,1659,1660,1661,1662,1663,1664,1665,1666,1667,1668,1669,1670,1671,1672,1673,1674
  176. 1508  GOTO 1515
  177. 1509 RN = RN -25: ON RN GOSUB 1675,1676,1677,1678,1679,1680,1681,1682,1683,1684,1685,1686,1687,1688,1689,1690,1691,1692,1693,1694,1695,1696,1697,1698,1699
  178. 1515 S$ = T$: GOTO 1545
  179. 1540 S$ =  LEFT$(S$, LEN(S$) -1)
  180. 1545  FOR X = 1 TO 20: HTAB 19
  181. 1550  FOR I = 1 TO 3:S =  PEEK(Q +48): NEXT I
  182. 1560 RN =  INT( RND(1) *50) +1: IF RN >25  THEN 1563
  183. 1561  ON RN GOSUB 1650,1651,1652,1653,1654,1655,1656,1657,1658,1659,1660,1661,1662,1663,1664,1665,1666,1667,1668,1669,1670,1671,1672,1673,1674
  184. 1562  GOTO 1568
  185. 1563 RN = RN -25: ON RN GOSUB 1675,1676,1677,1678,1679,1680,1681,1682,1683,1684,1685,1686,1687,1688,1689,1690,1691,1692,1693,1694,1695,1696,1697,1698,1699
  186. 1568  PRINT T$;: FOR I = 1 TO 20: NEXT I
  187. 1570  HTAB 19: PRINT "              ";
  188. 1580  FOR I = 1 TO 3 *X: NEXT I,X
  189. 1590 X = 19 - INT(( LEN(S$) +7 +T)/2)
  190. 1592  HTAB 1: CALL  -868: HTAB X: PRINT "IT'S A";
  191. 1593  IF  LEFT$(S$,1) < >"A"  AND  LEFT$(S$,1) < >"E"  AND  LEFT$(S$,1) < >"I"  AND  LEFT$(S$,1) < >"O"  AND  LEFT$(S$,1) < >"U"  THEN 1595
  192. 1594  PRINT "N";:T = 1
  193. 1595  PRINT " ";S$;"!<CTRL-G><CTRL-G><CTRL-G><CTRL-G> "
  194. 1600  HTAB X +7 +T: FOR I = 1 TO  LEN(S$): PRINT "-";: NEXT I
  195. 1630  PRINT : GOSUB 1860: GOTO 450
  196. 1640  REM === FAKE ANSWERS ===
  197. 1650 T$ = "WEENY": RETURN 
  198. 1651 T$ = "CHOCOLATE CAKE": RETURN 
  199. 1652 T$ = "DINOSAUR": RETURN 
  200. 1653 T$ = "TREE": RETURN 
  201. 1654 T$ = "SPOON": RETURN 
  202. 1655 T$ = "DANDILION": RETURN 
  203. 1656 T$ = "WEASEL": RETURN 
  204. 1657 T$ = "BEANSTALK": RETURN 
  205. 1658 T$ = "TABLECLOTH": RETURN 
  206. 1659 T$ = "EGGPLANT": RETURN 
  207. 1660 T$ = "HAIR DRYER": RETURN 
  208. 1661 T$ = "DOUGHNUT": RETURN 
  209. 1662 T$ = "HEATER": RETURN 
  210. 1663 T$ = "GIRDLE": RETURN 
  211. 1664 T$ = "CURTAIN": RETURN 
  212. 1665 T$ = "SEE SAW": RETURN 
  213. 1666 T$ = "RAISIN BOX": RETURN 
  214. 1667 T$ = "T-SQUARE": RETURN 
  215. 1668 T$ = "HOUSE": RETURN 
  216. 1669 T$ = "MOSQUITO": RETURN 
  217. 1670 T$ = "CLOCK RADIO": RETURN 
  218. 1671 T$ = "SANDWICH": RETURN 
  219. 1672 T$ = "JOGGING SHOE": RETURN 
  220. 1673 T$ = "NAIL FILE": RETURN 
  221. 1674 T$ = "FRUIT CAKE": RETURN 
  222. 1675 T$ = "FRIED EGG": RETURN 
  223. 1676 T$ = "BROWN BAG": RETURN 
  224. 1677 T$ = "BUN WARMER": RETURN 
  225. 1678 T$ = "SOCK": RETURN 
  226. 1679 T$ = "SWING": RETURN 
  227. 1680 T$ = "NECKLACE": RETURN 
  228. 1681 T$ = "PENCIL": RETURN 
  229. 1682 T$ = "WITCH": RETURN 
  230. 1683 T$ = "PICKLE": RETURN 
  231. 1684 T$ = "SHOVEL": RETURN 
  232. 1685 T$ = "WORM": RETURN 
  233. 1686 T$ = "ORANGE": RETURN 
  234. 1687 T$ = "STAPLER": RETURN 
  235. 1688 T$ = "CAN OF BEANS": RETURN 
  236. 1689 T$ = "BEER CAN": RETURN 
  237. 1690 T$ = "NOODLE": RETURN 
  238. 1691 T$ = "BELT LOOP": RETURN 
  239. 1692 T$ = "EARRING": RETURN 
  240. 1693 T$ = "SCREEN DOOR": RETURN 
  241. 1694 T$ = "SCREWDRIVER": RETURN 
  242. 1695 T$ = "TELEVISION": RETURN 
  243. 1696 T$ = "FAUCET": RETURN 
  244. 1697 T$ = "SQUIRREL": RETURN 
  245. 1698 T$ = "MATCH BOOK": RETURN 
  246. 1699 T$ = "COMIC BOOK": RETURN 
  247. 1850  REM === MENU/REPEAT? ===
  248. 1860  FOR I = 1 TO 999: NEXT I
  249. 1870  VTAB 24: HTAB 1: PRINT "( ANY KEY = REPEAT.   <RETURN> = MENU.)";
  250. 1880  COLOR= 6: PLOT 1,47: PLOT 21,47
  251. 1890 K =  PEEK(Q): IF K <128  THEN 1890
  252. 1892  POKE Q +16,0: IF K < >141  THEN  RETURN 
  253. 1894  POP :II = 2: TEXT 
  254. 1900  HOME : GOTO 240
  255. 1910  REM <CTRL-M><CTRL-M>==========<CTRL-M>21 NUMBERS<CTRL-M>==========  
  256. 1920  HOME : VTAB 9: HTAB 12: PRINT "21 NUMBERS"
  257. 1930 T =  -1:V = 2:J = 0
  258. 1935  REM === SHUFFLE ===
  259. 1940  FOR X = 1 TO 21
  260. 1960 A(X) =  INT( RND(1) *100): IF X = 1  THEN 1980
  261. 1970  FOR Y = 1 TO X -1: IF A(X) = A(Y)  THEN 1960
  262. 1972  NEXT Y
  263. 1980  NEXT X: HOME 
  264. 1990  REM === DEAL ===
  265. 2000  FOR X = 1 TO 21
  266. 2002 T = T +10: IF T >30  THEN T = 9
  267. 2004  IF (X -1) - INT((X -1)/3) *3 = 0  THEN V = V +2
  268. 2010  VTAB V: HTAB T: INVERSE : PRINT " ";A(X);" ": NORMAL 
  269. 2020  POKE 0,A(X) *2
  270. 2022  POKE 1,4
  271. 2024  CALL MU
  272. 2030  VTAB V: HTAB T: PRINT " ";
  273. 2031  IF J < >3  THEN 2034
  274. 2032  PRINT IT;: GOTO 2038
  275. 2034  PRINT A(X);
  276. 2038  PRINT "  "
  277. 2042  NEXT : PRINT 
  278. 2045  IF J = 3  THEN 2210
  279. 2050  VTAB 1: PRINT "         A         B         C                  ----      ----      ----"
  280. 2060  VTAB 18: HTAB 8
  281. 2070  PRINT "--------------------------": HTAB 9
  282. 2080  REM === ASK FOR COLUMN ===
  283. 2090  IF J = 0  THEN 2100
  284. 2092  PRINT "FIND THE SAME NUMBER...  ": PRINT : GOTO 2110
  285. 2100  PRINT "PICK A NUMBER FROM ABOVE.": PRINT 
  286. 2110  HTAB 9: PRINT "WHICH COLUMN-- A, B OR C?"
  287. 2120  HTAB 8: PRINT "--------------------------"
  288. 2130  COLOR= 15: PLOT 32,40: COLOR= 7: PLOT 32,41
  289. 2140 K =  PEEK(Q): IF K <193  OR K >195  THEN 2140
  290. 2142  POKE Q +16,0
  291. 2150  VTAB 21: CALL  -868: VTAB 19: CALL  -868
  292. 2170  IF K = 193  THEN  GOSUB 2300
  293. 2171  IF K = 194  THEN  GOSUB 2330
  294. 2172  IF K = 195  THEN  GOSUB 2360
  295. 2180 J = J +1:IT = B(11): IF J = 3  THEN 2200
  296. 2190  FOR X = 1 TO 21:A(X) = B(X): NEXT X
  297. 2200 V = 2:T =  -1: GOTO 2000
  298. 2210  INVERSE : VTAB 19: HTAB 9: PRINT "                       ": HTAB 9: PRINT "                       "
  299. 2220  HTAB 9: PRINT "                       "
  300. 2230  REM  END:                            ----
  301. 2240  VTAB 20: HTAB 13: PRINT "  I GIVE UP!<CTRL-G><CTRL-G>"
  302. 2250  VTAB 1: HTAB 9: PRINT " A  ";: HTAB 19: PRINT " B  ";: HTAB 29: PRINT " C  "
  303. 2270  NORMAL 
  304. 2280  GOSUB 1860: GOTO 1920
  305. 2290  REM === RESHUFFLE ===
  306. 2300  INVERSE : VTAB 1: HTAB 9: PRINT " A  ": NORMAL 
  307. 2310  FOR X = 1 TO 21: IF X <8  THEN XX = 1
  308. 2312  IF X >7  AND X <15  THEN XX = 23
  309. 2314  IF X >14  THEN XX = 42
  310. 2320  GOTO 2380
  311. 2330  INVERSE : VTAB 1: HTAB 19: PRINT " B  ": NORMAL 
  312. 2340  FOR X = 1 TO 21: IF X <8  THEN XX = 2
  313. 2344  IF X >7  AND X <15  THEN XX = 22
  314. 2346  IF X >14  THEN XX = 42
  315. 2350  GOTO 2380
  316. 2360  INVERSE : VTAB 1: HTAB 29: PRINT " C  ": NORMAL 
  317. 2370  FOR X = 1 TO 21: IF X <8  THEN XX = 2
  318. 2372  IF X >7  AND X <15  THEN XX = 21
  319. 2374  IF X >14  THEN XX = 43
  320. 2380 N = A((3 *X) -XX)
  321. 2390 B(X) = N: NEXT X: RETURN 
  322. 2930  REM <CTRL-M><CTRL-M>============<CTRL-M>CARD SCANNER<CTRL-M>============  
  323. 2940  HOME : INVERSE 
  324. 2950  VTAB 1: HTAB 11: PRINT ":                 :": HTAB 11: PRINT "  CARD IDENTIFIER  ": HTAB 11: PRINT ":                 :"
  325. 2960  NORMAL : PRINT 
  326. 2970  PRINT "THIS COMPUTER WILL": PRINT "IDENTIFY ANY CARD": PRINT "USING AN ADVANCED": PRINT "VIDEO SCANNING": PRINT "TECHNIQUE."
  327. 2980  PRINT : PRINT "   INSTRUCTIONS:": PRINT "---------------------"
  328. 2990  PRINT "1. PRESS YOUR CARD": PRINT "   AGAINST THE SCREEN->": PRINT 
  329. 3000  PRINT "2. TYPE 'RUN'.": PRINT : PRINT "3. PRESS 'RETURN'"
  330. 3010  PRINT "---------------------"
  331. 3020  VTAB 22: PRINT "]    <-TYPE 'RUN'."
  332. 3030  INVERSE 
  333. 3040  FOR I = 5 TO 22: VTAB I: HTAB 24
  334. 3050  PRINT "@@@@@@@@@@@@@@@@@";: NEXT I
  335. 3060  NORMAL : COLOR= 6: PLOT 1,43
  336. 3070 K =  PEEK(Q): IF K <160  THEN 3070
  337. 3072  POKE Q +16,0:N = K
  338. 3080  VTAB 22: HTAB 2: PRINT "R";: PLOT 2,43
  339. 3090 K =  PEEK(Q): IF K <160  THEN 3090
  340. 3092  POKE Q +16,0:S = K
  341. 3100  HTAB 3: PRINT "U";: PLOT 3,43
  342. 3110  IF  PEEK(Q) <160  THEN 3110
  343. 3112  POKE Q +16,0
  344. 3120  HTAB 4: PRINT "N";: PLOT 4,43
  345. 3130  IF  PEEK(Q) <141  THEN 3130
  346. 3132  POKE Q +16,0
  347. 3140  HTAB 5: PRINT "              ": VTAB 5: HTAB 24
  348. 3150  POKE 32,23: POKE 34,4: POKE 35,22: POKE 33,17
  349. 3160 C$ = ""
  350. 3170  IF (N <176  OR N >185)  AND (N < >193  AND N < >202  AND N < >203  AND N < >209)  THEN 3260
  351. 3180 N = N -176: IF N = 17  THEN N = 1
  352. 3182  IF N = 0  THEN N = 10
  353. 3190  IF N = 26  THEN C$ = "JACK"
  354. 3192  IF N = 27  THEN C$ = "KING"
  355. 3194  IF N = 33  THEN C$ = "QUEEN"
  356. 3200  IF N = 17  OR N = 1  THEN C$ = "ACE"
  357. 3210  IF S = 195  THEN C$ = C$ +" OF CLUBS"
  358. 3220  IF S = 196  THEN C$ = C$ +" OF DIAMONDS"
  359. 3230  IF S = 200  THEN C$ = C$ +" OF HEARTS"
  360. 3240  IF S = 211  THEN C$ = C$ +" OF SPADES"
  361. 3250  GOTO 3270
  362. 3260 C$ = "PLAYING CARD "
  363. 3270  FOR I = 1 TO 61
  364. 3280 S =  PEEK( -16304)
  365. 3290  NORMAL : IF I - INT(I/2) *2 = 0  THEN  INVERSE 
  366. 3300  POKE 0, INT( RND(1) *49) +1
  367. 3310  POKE 1,2
  368. 3320  CALL MU
  369. 3330  PRINT " ";: IF N >1  AND N <11  THEN  PRINT N;
  370. 3332  PRINT C$;" ";: NEXT I
  371. 3340  TEXT :S =  PEEK( -16304): TEXT 
  372. 3350  POKE 32,0: POKE 33,40: POKE 34,0: POKE 35,24
  373. 3360  GOSUB 1860: GOTO 2930
  374. 5000  REM === TYPING NOISE ===
  375. 5005  FOR X = 1 TO  LEN(T$): PRINT  MID$ (T$,X,1);: IF  MID$ (T$,X,1) = " "  THEN 5020
  376. 5010  FOR U = 1 TO 3:S =  PEEK(Q +48): NEXT U
  377. 5020  FOR U = 1 TO 6: NEXT U,X: RETURN 
  378. 6000  REM <CTRL-M><CTRL-M>========<CTRL-M>NEXTWORD<CTRL-M>========
  379. 6002 X = 0:Z = 0
  380. 6005  HOME : INVERSE 
  381. 6010  PRINT "     ";: HTAB 7: PRINT "     ": PRINT " NEXT";: HTAB 7: PRINT "WORD ": PRINT " ----";: HTAB 7: PRINT "---- ": PRINT "     ";: HTAB 7: PRINT "     "
  382. 6015  NORMAL : VTAB 1
  383. 6020  HTAB 13: PRINT "1.YOU TYPE A WORD.": HTAB 13: PRINT "2.THE COMPUTER TYPES THE": HTAB 13: PRINT "  NEXT LOGICAL WORD."
  384. 6025  HTAB 13: PRINT "3.YOU TYPE THE NEXT, ETC."
  385. 6030  INVERSE : VTAB 6: HTAB 1: PRINT " YOUR FIRST WORD: ";: NORMAL : HTAB 20: INPUT C$: IF C$ = ""  THEN 6030
  386. 6032  FOR I =  LEN(C$) TO 1  STEP  -1:TEST =  ASC( MID$ (C$,I,1)): IF TEST >64  AND TEST <91  THEN 6035
  387. 6033  NEXT I: GOTO 6002
  388. 6035 I = TEST -64
  389. 6037  ON I GOSUB 6165,6170,6175,6180,6185,6190,6195,6200,6205,6210,6215,6220,6225,6230,6235,6240,6245,6250,6255,6260,6265,6270,6275,6280,6285,6290
  390. 6040  NORMAL : HTAB 1: PRINT " COMPUTER'S WORD:   ";S$: PRINT 
  391. 6044 J = 0
  392. 6045 J = J +1
  393. 6050  POKE 0, INT( RND(1) *200) +5
  394. 6055  POKE 1,3
  395. 6060  CALL MU
  396. 6065  FOR I = 1 TO 25: NEXT I
  397. 6067  IF J <10  THEN 6045
  398. 6075  INVERSE : PRINT "  YOUR NEXT WORD: ";
  399. 6080  NORMAL : HTAB 20: INPUT C$: IF C$ = ""  THEN 6080
  400. 6085  IF  LEFT$(C$,1) =  RIGHT$(S$,1)  THEN 6105
  401. 6090 X = 0: FOR J = 1 TO 50:S =  PEEK(Q +48): NEXT J
  402. 6095 Z = Z +1: IF Z = 3  THEN 6150
  403. 6100  INVERSE : PRINT " WRONG! TRY AGAIN:";: GOTO 6080
  404. 6105  NORMAL : VTAB  PEEK(37): PRINT "                  ";
  405. 6110 Y =  INT( RND(1) *99) +9: FOR J = Y TO Y +100  STEP 10
  406. 6115  POKE 0,250 -J
  407. 6120  POKE 1,9
  408. 6125  CALL MU
  409. 6130  NEXT J:Z = 0
  410. 6135  INVERSE : HTAB 7: PRINT "   CORRECT! "
  411. 6140 X = X +1: IF X = 3  THEN 6155
  412. 6145  GOTO 6032
  413. 6150  NORMAL : PRINT : PRINT "THREE WRONG IN A ROW-- YOU LOSE!": FOR I = 1 TO 123:S =  PEEK(Q +48): NEXT I: GOTO 6160
  414. 6155  NORMAL : PRINT : PRINT "I THINK YOU'VE GOT ME!<CTRL-G><CTRL-G><CTRL-G>-- YOU WIN!!"
  415. 6160  GOSUB 1850: GOTO 6002
  416. 6165 S$ = "ARROW": RETURN 
  417. 6170 S$ = "BOX": RETURN 
  418. 6175 S$ = "CANE": RETURN 
  419. 6180 S$ = "DOLLAR": RETURN 
  420. 6185 S$ = "ELEPHANT": RETURN 
  421. 6190 S$ = "FORK": RETURN 
  422. 6195 S$ = "GATE": RETURN 
  423. 6200 S$ = "HAT": RETURN 
  424. 6205 S$ = "IGLOO": RETURN 
  425. 6210 S$ = "JAIL": RETURN 
  426. 6215 S$ = "KITE": RETURN 
  427. 6220 S$ = "LADDER": RETURN 
  428. 6225 S$ = "MARBLE": RETURN 
  429. 6230 S$ = "NUMBER": RETURN 
  430. 6235 S$ = "OWL": RETURN 
  431. 6240 S$ = "PIN": RETURN 
  432. 6245 S$ = "QUEEN": RETURN 
  433. 6250 S$ = "RAKE": RETURN 
  434. 6255 S$ = "SNAIL": RETURN 
  435. 6260 S$ = "TRIANGLE": RETURN 
  436. 6265 S$ = "UMBRELLA": RETURN 
  437. 6270 S$ = "VALENTINE": RETURN 
  438. 6275 S$ = "WAGON": RETURN 
  439. 6280 S$ = "XYMURGY": RETURN 
  440. 6285 S$ = "YOYO": RETURN 
  441. 6290 S$ = "ZERO": RETURN 
  442. 32000  POKE 771,173: POKE 772,48: POKE 773,192: POKE 774,136: POKE 775,208: POKE 776,4: POKE 777,198: POKE 778,1: POKE 779,240: POKE 780,8: POKE 781,202: POKE 782,208: POKE 783,246: POKE 784,166: POKE 785,0: POKE 786,76: POKE 787,3: POKE 788,3: POKE 789,96
  443. 32762  DIM A(100),B(100): TEXT : NORMAL :Q =  -16384:MU = 771: RETURN 
  444. 63900  TEXT : HOME : NORMAL : VTAB 10: HTAB 5: PRINT "BEAGLE BAG": HTAB 5: PRINT "------------------"
  445. 63910  VTAB 12: PRINT "<M> MENU": PRINT "<C> CONTINUE THIS GAME": PRINT "<Q> QUIT": HTAB 5: PRINT "------------------": PRINT "    SELECT:";: GET A$: PRINT A$: IF A$ = "Q"  THEN  END 
  446. 63920  IF A$ = "M"  THEN  POKE 768,12: PRINT  CHR$(4);"RUN SHORT MENU"
  447. 63930  IF A$ = "C"  THEN  RUN 
  448. 63940  GOTO 63900